From 290370630e3af383cf8dfdcd37e95ccccc71737f Mon Sep 17 00:00:00 2001
From: notwa <cloningdonor@gmail.com>
Date: Thu, 27 Jun 2013 11:54:53 -0700
Subject: [PATCH]

---
 render.zsh | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 render.zsh

diff --git a/render.zsh b/render.zsh
new file mode 100644
index 0000000..1caa5fe
--- /dev/null
+++ b/render.zsh
@@ -0,0 +1,54 @@
+#!/bin/zsh
+in=(**/*.(otf|ttf))
+size=16
+outdir='rendered-again'
+lipsum='Lorem ipsum dolor sit amet, consectetur adipiscing elit. Donec a diam lectus. Sed sit amet ipsum mauris. Maecenas congue ligula ac quam viverra nec consectetur ante hendrerit. Donec et mollis dolor. Praesent et diam eget libero egestas mattis sit amet vitae augue. Nam tincidunt congue enim, ut porta lorem lacinia consectetur. Donec ut libero sed arcu vehicula ultricies a non tortor. Lorem ipsum dolor sit amet, consectetur adipiscing elit. Aenean ut gravida lorem. Ut turpis felis, pulvinar a semper sed, adipiscing id dolor. Pellentesque auctor nisi id magna consequat sagittis. Curabitur dapibus enim sit amet elit pharetra tincidunt feugiat nisl imperdiet. Ut convallis libero in urna ultrices accumsan. Donec sed odio eros. Donec viverra mi quis quam pulvinar at malesuada arcu rhoncus. Cum sociis natoque penatibus et magnis dis parturient montes, nascetur ridiculus mus. In rutrum accumsan ultricies. Mauris vitae nisi at sem facilisis semper ac in est.'
+
+mkdir -p $outdir
+
+flags=(-q --font $size --pixels --justify --hinting=auto)
+flags+=(--width=$((size*32)) --margin=$((size*4))\ $((size*5)))
+
+cleanup() {
+    rm -f $tf $out
+    rm -rf $td
+    exit
+}
+trap cleanup INT
+
+tf=$(mktemp)
+td=$(mktemp -d)
+<<<"$lipsum">$tf
+export FONTCONFIG_PATH=$td
+
+<<<'<?xml version="1.0"?>
+<!DOCTYPE fontconfig SYSTEM "fonts.dtd">
+<fontconfig>
+    <dir>'$td'</dir>
+    <cachedir>'$td'</cachedir>
+    <include ignore_missing="yes">/etc/fonts/infinality/infinality.conf</include>
+    <config></config>
+</fontconfig>
+'>>$td/fonts.conf
+
+for font in ${in[@]}; do
+    filename=${font:t}
+    stripped=${filename:r}
+    out=$outdir/$stripped.png
+    [ -s $out ] && continue
+
+    ok=1
+    cp $font $td
+    pango-view ${flags[@]} -o $out $tf 2>&1 | while read -r; do
+        <<<$REPLY >&2
+        ok=0
+    done
+    [ $ok -eq 1 ] && <<<$stripped || {
+        <<<$'\e[7m'$stripped$'\e[0m'
+        rm -f $out
+    }
+
+    rm -f $td/$filename $td/*.cache-4
+done
+
+cleanup